На главную Наши проекты:
Журнал   ·   Discuz!ML   ·   Wiki   ·   DRKB   ·   Помощь проекту
ПРАВИЛА FAQ Помощь Участники Календарь Избранное RSS
msm.ru
! правила раздела Алгоритмы
1. Помните, что название темы должно хоть как-то отражать ее содержимое (не создавайте темы с заголовком ПОМОГИТЕ, HELP и т.д.). Злоупотребление заглавными буквами в заголовках тем ЗАПРЕЩЕНО.
2. При создании темы постарайтесь, как можно более точно описать проблему, а не ограничиваться общими понятиями и определениями.
3. Приводимые фрагменты исходного кода старайтесь выделять тегами code.../code
4. Помните, чем подробнее Вы опишете свою проблему, тем быстрее получите вразумительный совет
5. Запрещено поднимать неактуальные темы (ПРИМЕР: запрещено отвечать на вопрос из серии "срочно надо", заданный в 2003 году)
6. И не забывайте о кнопочках TRANSLIT и РУССКАЯ КЛАВИАТУРА, если не можете писать в русской раскладке :)
Модераторы: Akina, shadeofgray
  
> загляни-помоги!
    не знаю, куда было запостить тему, поэтому запостил сюда.
    проблема такова, что мне надо триангулировать нарисованную в 3dmax фигуру, а как его заставить это сделать, я не знаю.
    истоки этой проблемы лежат в том, что надо крутить-вертеть и рисовать фигуру в пространстве, и мне подумалось, что считать координаты фигуры лень, и пусть 3dmax это сделает, а я буду  рисовать только треугольнички, используя алгоритм z-буфера.
    заранее благодарен за комментарии, советы и помощь.
      Выделяешь фигуру, далее конвертируешь ее в Editable Mesh, потом сохраняешь ее, например, таким сткриптом:
      ExpandedWrap disabled
        -------------------------------------------------------------------------------------
        -- MEGA2.ms
        -------------------------------------------------------------------------------------
        utility MEGExport "MEGA2"
        (
              local ostream, tabs = ""
         
              group "Options"
              (
                    checkbox cb_exportSelOnly "Selected Only"
                    checkbox cb_exportTexVerts "Export texture vertices"
                    checkbox cb_exportAbsoluteCoord "Use absolute coordinates"
              )
              group "Frames"
              (
                    spinner sp_start "From:" range:[animationrange.start,animationrange.end,animationrange.start] type:#Integer
                    spinner sp_end "To:" range:[animationrange.start,animationrange.end,animationrange.start] type:#Integer
                spinner sp_step "Step:" range:[animationrange.start + 1,animationrange.end,animationrange.start + 1] type:#Integer
                )
         
              button btn_export "Save As..." width:100
              
              -------------------------------------------------------------------------------------
                    function ExportTarget obj =
              (
                    Format (tabs+"myobj.target = Targetobject()\n") to:ostream
                    Format (tabs+"myobj.target.name = \"\%\"\n") obj.target.name to:ostream
                    Format (tabs+"myobj.target.transform = \%\n") obj.target.transform to:ostream
                    Format (tabs+"myobj.target.position += createPos\n") to:ostream
              )
         
                -------------------------------------------------------------------------------------
                function ExportGeneric obj =
              (
                    Format (tabs+"\%\n") (ClassOf obj) to:ostream
                    Format (tabs+"\%  \%  \%\n") (obj.pos.x) (obj.pos.y) (obj.pos.z) to:ostream
         
                    for prop in GetPropNames obj do
                    (
                          local propname = prop as String
                          local propval  = GetProperty obj prop
         
                          if (ClassOf obj) == Hedra and prop == #vertices then continue
         
                          if propval != undefined then
                                Format (tabs+"\t\% \%\n") propname propval to:ostream
                    )
                    
                    if obj.target != undefined then
                          ExportTarget obj
         
                    Format (tabs+"end \%\n") (ClassOf obj) to:ostream
              )
              -------------------------------------------------------------------------------------
              function ExportTexVertices MeshObj =
              (
                    Format (tabs+"\%\n") (MeshObj.material.maps[2].Bitmap) to:ostream
                    Format (Tabs+"\% \% \% \%\n") (MeshObj.material.ambient.r as Integer) (MeshObj.material.ambient.g as Integer) (MeshObj.material.ambient.b as Integer) ((MeshObj.material.opacity*2.55) as Integer)to:ostream
                Format (tabs+"numtverts numtvfaces\n") to:ostream
                    Format (tabs+"   \%        \%\n") meshObj.numTVerts meshObj.numfaces to:ostream            
         
                    -- Write texture vertices
                    if MeshObj.numTVerts > 0 then
                    (
                              Format (tabs+"Texture vertices:\n") to:ostream
         
                          for i = 1 to meshObj.NumTVerts do
                          (
                                Format (tabs+"\t\% \% \%\n") (GetTVert meshObj i).x (GetTVert meshObj i).y (GetTVert meshObj i).z to:ostream
                          )
                          Format (tabs + "end texture vertices\n") to:ostream
                    )
                    
                    -- Write texture faces
                    if meshObj.numfaces > 0 then
                    (
                          Format (tabs+"Texture faces:\n") to:ostream
         
                          for i = 1 to meshObj.numfaces do
                          (
                                Format (tabs+"\t\% \% \%\n") ((GetTVFace meshObj i).x as Integer) ((GetTVFace meshObj i).y as Integer) ((GetTVFace meshObj i).z as Integer) to:ostream
                          )
                          Format (tabs + "end texture faces\n") to:ostream
                    )
                    
              )
         
              -------------------------------------------------------------------------------------
              
              function ExportMesh meshObj =
              (
                    Format (tabs+"TriMesh()\n") to:ostream
                    Format (tabs+"numverts numfaces\n") to:ostream
                    Format (tabs+"   \%        \%\n") meshObj.numverts meshObj.numfaces to:ostream
         
                    Format(tabs+"\t\% \% \%\n") (meshObj.Center.x) (meshObj.Center.y) (meshObj.Center.z) to:ostream       
         
                    -- Write vertices
                    if meshObj.numVerts > 0 then
                    (
                  Format (tabs+"Mesh vertices:\n") to:ostream
         
                  if cb_exportAbsoluteCoord.Checked then
                       (
                                for i = 1 to meshObj.numVerts do
                                (
                                      Format (tabs+"\t\% \% \%\n") ((GetVert meshObj i).x) ((GetVert meshObj i).y) ((GetVert meshObj i).z) to:ostream       
                                )
                       )
                       else
                       (
                                 for i = 1 to meshObj.numVerts do
                                (
                                      Format (tabs+"\t\% \% \%\n") ((GetVert meshObj i).x - meshObj.Center.x) ((GetVert meshObj i).y - meshObj.Center.y) ((GetVert meshObj i).z - meshObj.Center.z) to:ostream       
                                )
                       )      
                  Format (tabs+"end vertices\n") to:ostream
         
                    )
         
         
                    -- Write faces
                    if meshObj.numFaces > 0 then
                    (
                          Format (tabs+"Mesh faces:\n") to:ostream
                          for i = 1 to meshObj.numFaces do
                                (
                                Format (tabs+"\t\% \% \%\n") ((GetFace meshObj i).x as Integer) ((GetFace meshObj i).y as integer) ((GetFace meshObj i).z as Integer) to:ostream
                                )
                          Format (tabs+"end faces\n") to:ostream
                    )
         
         
                    -- Write faset normals
                    if meshObj.numFaces > 0 then
                    (
                          Format (tabs+"Faset normals:\n") to:ostream
                          for i = 1 to meshObj.numFaces do
                          (      Format (tabs+"\t\% \% \%\n") (GetFaceNormal meshObj i).x (GetFaceNormal meshObj i).y (GetFaceNormal meshObj i).z to:ostream
                          )
                          Format (tabs+"end faset normals\n") to:ostream
                    )
                    
         
                    -- Write smoothing normals
                    if meshObj.numVerts > 0 then
                    (
                          Format (tabs+"Smooth normals:\n") to:ostream
                          for i = 1 to meshObj.numVerts do
                          (
                                Format (tabs+"\t\% \% \%\n") (GetNormal meshObj i).x (GetNormal meshObj i).y (GetNormal meshObj i).z to:ostream       
                          )
                          Format (tabs+"end smooth normals\n") to:ostream
                    )
                    
                    Format (tabs+"end mesh\n") to:ostream
                    
                    
                    -- Write texture coordinates
                    if cb_exportTexVerts.checked then
                          (
                                      Format "New Texture:\n" to:ostream
                                      ExportTexVertices meshObj
                                       Format "end of texture\n"      to:ostream
                          )
                          
                    
                    
              )
         
            -------------------------------------------------------------------------------------
              -------------------------------------------------------------------------------------
              function ExportNode node =
              (
                    Format "New object\n" to:ostream
                    Format "\%\n" (node.name) to:ostream
                    if SuperClassOf node == GeometryClass and ClassOf node == Editable_mesh then
                          ExportMesh node
                    else if (not (ClassOf node == Targetobject and node.isTarget)) then
                          ExportGeneric node
                    else
                          return false
                Format "End object\n" to:ostream
                    return true
              )
         
              -------------------------------------------------------------------------------------
              function RecursiveExportNode node =
              (
                    if (ExportNode node) == false then
                          return false
         
                    -- Recurse children before writing this node
                    for child in node.children do
                          RecursiveExportNode child
                          
              )
         
              -------------------------------------------------------------------------------------
              function ExportGMS =
              (
                    if cb_exportSelOnly.checked then
                    (
                          for node in selection do
                                ExportNode node
                          
                    )
                    else
                    (
                          for node in rootnode.children do
                                RecursiveExportNode node
                    )
              )
         
              -------------------------------------------------------------------------------------
              function GetSaveFileStream =
              (
                    fname = GetSaveFileName types:"Game Meshes Files (*.gms)|*.gms|All Files(*.*)|*.*|"
                    if fname == undefined then
                          return undefined
         
                    ostream = CreateFile fname
                    if ostream == undefined then
                    (
                          MessageBox "Couldn't open file for writing !"
                          return undefined
                    )
         
                    return ostream
              )
         
              -------------------------------------------------------------------------------------
              on btn_export pressed do
              (
                    ostream = GetSaveFileStream()
                    if ostream != undefined then
                    (
                          i = sp_start.value
                          while i <= sp_end.value do
                          (
                                slidertime = i
                                ExportGMS()
                                i += sp_step.value
                          )
                    
                    --      if cb_exportTexVerts.checked then
                    --      (
                    --            for node in selection do
                    --            (
                    --                 if SuperClassOf node == GeometryClass and ClassOf node == Editable_mesh then
                    --                  (
                    --                  Format "New Texture:\n" to:ostream
                    --                  ExportTexVertices node
                    --                  Format "end of texture\n"      to:ostream
                    --                  )
                    --            )
                    --      )
         
                            Format "end of file" to:ostream
                          Close ostream
                    )
              )
              --------------------------------------------------------------------------------------
              on sp_start changed value do
              (
                    slidertime = sp_start.value
              )
              on MEGExport open do
               (
                   max views redraw
               )
              
         
        ) -- End MEGExport

      Вроде то, если я правильно понял суть вопроса...
        спасибо. попробуем.
          я не очень понял, как пользоваться скримто. вот создал я его, сохранил. сделал, как ты сказал, т.е. конвертнул в editable mesh, даже скрипт запускал, а результат-то где?
          сорри, я в 3dmax работаю только-только, но мне от него только это и надо.
            Значит у меня сейчас 3dsmax`а нет, поэтому пишу по памяти.
            Короче, есть такая панелька, где лежат кнопки "Создать", "Изменить", "Иерархия", две какие-то фигни и кнопка "Утилиты". Так в жмешь на эту самую правую кнопку, там ищешь пункт "MaxScript", нажимаешь в нем "Run Script", выбираешь нужный файлик. Где-то недалеко от этого места должна появится новая утилита "MEGA2" (нужно хорошо поискать, с первого раза можно и не найти :)). Так вот открываешь эту новую вкладку, дальше все должно быть понятно: выделяешь свой объект (который ты преобразовал в Editable Mesh), настраиваешь параметры (нужны ли текстуры в выходном файле, сохранять ли анимацию), жмешь "Сохранить". В созхданном файле тебе  будет нужна только начальная часть (ведь, как я понял, нормали и текстуры тебе не нужны).
            Вот вроде и все.
              да,спасибо.
              Цитата
              В созхданном файле тебе  будет нужна только начальная часть (ведь, как я понял, нормали и текстуры тебе не нужны).

              да, мне ничего не нужно кроме координат треугольников, которые там будут, я правильно понимаю?
                Там будет что-то вроде этого:
                Цитата
                numverts numfaces
                  8        12
                     5.0 0.0 10.0
                Mesh vertices:
                     -10.0 -100.0 0.0
                     20.0 -100.0 0.0
                     -10.0 100.0 0.0
                     20.0 100.0 0.0
                     -10.0 -100.0 20.0
                     20.0 -100.0 20.0
                     -10.0 100.0 20.0
                     20.0 100.0 20.0
                end vertices
                Mesh faces:
                     1 3 4
                     4 2 1
                     5 6 8
                     8 7 5
                     1 2 6
                     6 5 1
                     2 4 8
                     8 6 2
                     4 3 7
                     7 8 4
                     3 1 5
                     5 7 3
                end faces

                То есть набор координат точек, и номера точек из которых будут состоять треугольники.
                  да, спасибо. это то, что мне надо. надо только научиться пользоваться твоим скриптом. эээх! атакуем 3dmax еще раз. ;D
                    Цитата albom, 18.10.03, 21:19:33
                    Значит у меня сейчас 3dsmax`а нет, поэтому пишу по памяти.
                    Короче, есть такая панелька, где лежат кнопки "Создать", "Изменить", "Иерархия", две какие-то фигни и кнопка "Утилиты". Так в жмешь на эту самую правую кнопку, там ищешь пункт "MaxScript", нажимаешь в нем "Run Script", выбираешь нужный файлик. Где-то недалеко от этого места должна появится новая утилита "MEGA2" (нужно хорошо поискать, с первого раза можно и не найти :)). Так вот открываешь эту новую вкладку, дальше все должно быть понятно: выделяешь свой объект (который ты преобразовал в Editable Mesh), настраиваешь параметры (нужны ли текстуры в выходном файле, сохранять ли анимацию), жмешь "Сохранить". В созхданном файле тебе  будет нужна только начальная часть (ведь, как я понял, нормали и текстуры тебе не нужны).
                    Вот вроде и все.

                    все вроде обыскал, но найти утилиту mega2 не могу. где она хоть находится примерно? ???
                      Значит, сначала находим это:
                      user posted image
                      Потом жмем "Run Script" и выбираем файлик mega2.ms (можно скачать еще и <<отсюда>>)
                      user posted image
                      Смотрим, что получилось, потом жмем мышкой на слово "MEGA2" (что выделено желтым цветом). Должен открытся новый раздел, как показано ниже:
                      user posted image

                      ЗЫ. В 3dsMax5 это точно работает.
                      Сообщение отредактировано: albom -
                        ааа! картинки с твоего сайта у меня не грузятся, как и сам сайт. :'( :'(
                        но я все-таки попробую найти утилиту mega2. :'( :'(
                        0 пользователей читают эту тему (0 гостей и 0 скрытых пользователей)
                        0 пользователей:


                        Рейтинг@Mail.ru
                        [ Script execution time: 0.0960 ]   [ 15 queries used ]   [ Generated: 16.11.26, 04:39 GMT ]