Интернет радио , как????

[Мамонт]

Скажите возможно ли на Бэсике сделать проигрыватель интернет радио! Если да то где инфу найти!

[Tri Repetae]

Ну.. если мы говорим о потоковом интернет-радио, то проще всего:
подключаем Active Movie Control Library (quartz.dll)

Private BasicAudio As IBasicAudio
Private MediaControl As IMediaControl
 
Public Function OpenRadio(RadioPath As String) As Boolean
On Local Error GoTo ErrHandler
    Call CleanUp    
    Set MediaControl = New FilgraphManager
    Call MediaControl.RenderFile(RadioPath)
    Set BasicAudio = MediaControl
    BasicAudio.Volume = 0
    BasicAudio.Balance = 0
    MediaControl.Run
    OpenRadio = True
Exit Function
ErrHandler: CleanUp
End Function
 
Public Sub StopRadio()
    If (ObjPtr(MediaControl) > 0) Then Call MediaControl.Stop
End Sub
 
Public Sub CleanUp()
On Local Error GoTo ErrHandler
    If ObjPtr(MediaControl) > 0 Then MediaControl.Stop
    If ObjPtr(BasicAudio) > 0 Then Set BasicAudio = Nothing
    If ObjPtr(MediaControl) > 0 Then Set MediaControl = Nothing
Exit Sub
ErrHandler: Err.Clear
End Sub

слушаем, к примеру, «13кнопку»

OpenRadio "mms://81.13.20.10/13button"

Сообщение отредактировано: SCINER - 16.09.07, 17:36

[Vasya2000]

M

Тема перенесена из Visual Basic -> Visual Basic. Общие вопросы.