Не работает обработчик событий MouseEvent

[diel]

package
{
    import flash.display.*;
    import flash.net.*;
    import flash.events.*;
    import flash.text.*;
    import flash.ui.*;
    import flash.media.Sound;
 
    public class main extends MovieClip
    //public class main extends Sprite
    {
        [Embed(source = "data/start_game.jpg")]
        private static const StartGame:Class;
 
        [Embed(source="data/click.mp3")]
        public var Click:Class;
 
        public function main()
        {
            var startgame:Bitmap = new StartGame();
            startgame.addEventListener(MouseEvent.CLICK, mouseHandler);
            this.addChild(startgame);
 
            function mouseHandler(mouseEvent:MouseEvent):void
            {
                //navigateToURL(new URLRequest("http://google.com"), "_blank");
                var smallSound:Sound = new Click() as Sound;
                smallSound.play();
            }
 
        }

Подскажите пожалуйста, из-за чего может не работать клик по картинке с последующей обработкой события внутри функции mouseHandler.
Заранее благодарю.

[piksel]

Потому что класс Bitmap не интерактивен Bitmap→DisplayObject→EventDispatcher→Object.
Используйте Sprite, который Sprite→DisplayObjectContainer→InteractiveObject→DisplayObject→EventDispatcher→Object
типа:

var startgame:Sprite = new Sprite();
startgame.buttonMode = true;
startgame.addEventListener(MouseEvent.CLICK, mouseHandler);
this.addChild(startgame);
var bmp:Bitmap = new StartGame();
startgame.addChild(bmp);

[diel]

Спасибо большое, очень помогли! Я не знал