Убить процесс перед удалением программы , Inno Setup

Здравствуйте. Подскажите как можно убить процесс перед началом удаления программы? При старте программы у меня получилось сделать.

function InitializeSetup(): Boolean;
begin
  If RunTask('Test.exe', false) then  
    begin                              
      if MsgBox('File Test.exe are using. Close this file and continue installing?', mbInformation, mb_YesNo) = idYes then
         begin                        
           KillTask('Test.exe');      
           Result:= True;
         end else                    
          Exit;                      
    end;
Result:=True;
end;

Функция KillTask и RunTask взяты с библиотеки isxdl.dll. Но почему то такой же код только для удаления не работает

function InitializeUninstall(): Boolean;
begin
   If RunTask('Test.exe', false) then  
    begin                              
      if MsgBox('File Test.exe are using. Close this file and continue uninstalling?', mbInformation, mb_YesNo) = idYes then
         begin                        
           KillTask('Test.exe');      
           Result:= True;
         end else                    
          Exit;                      
    end;
Result:=True;
end;

Подскажите как можно убыть процесс перед удалением, и если пользователь выбрал "Нет" , отменить удаление.

Ошибка была при загрузке загрузке длл.

function KillTask(ExeFileName: string): Integer;
external 'KillTask@files:ISTask.dll stdcall delayload';
 
function RunTask(FileName: string; bFullpath: Boolean): Boolean;
external 'RunTask@files:ISTask.dll stdcall delayload';

Но проблема так и не решилась. когда вместо files: я написал

function KillTask(ExeFileName: string): Integer;
external 'KillTask@{app}\ISTask.dll stdcall delayload';
 
function RunTask(FileName: string; bFullpath: Boolean): Boolean;
external 'RunTask@{app}\ISTask.dll stdcall delayload';

P.S. Библиотеку загрузил у каталог где установлена программа.

Source: ISTask.dll; DestDir: "{app}"

Как решить эту проблему. Буду раз за любую помощь.

Ошибка после изменений "An attempt was made to expand the "app" constant before it was inicialized"

Сообщение отредактировано: Craft - 14.02.11, 14:56

А если так?

function KillTask(ExeFileName: string): Integer;
external 'KillTask@files:ISTask.dll stdcall setuponly';
 
function RunTask(FileName: string; bFullpath: Boolean): Boolean;
external 'RunTask@files:ISTask.dll stdcall setuponly';
 
 
function KillTask(ExeFileName: string): Integer;
external 'KillTask@{app}\ISTask.dll stdcall uninstallonly';
 
function RunTask(FileName: string; bFullpath: Boolean): Boolean;
external 'RunTask@{app}\ISTask.dll stdcall uninstallonly';

PS: В директории Inno Setup\Examples есть пример CodeDll.iss, посмотри его.

Цитата Kray74 @ 14.02.11, 15:09

А если так?

function KillTask(ExeFileName: string): Integer;
external 'KillTask@files:ISTask.dll stdcall setuponly';
 
function RunTask(FileName: string; bFullpath: Boolean): Boolean;
external 'RunTask@files:ISTask.dll stdcall setuponly';
 
 
function KillTask(ExeFileName: string): Integer;
external 'KillTask@{app}\ISTask.dll stdcall uninstallonly';
 
function RunTask(FileName: string; bFullpath: Boolean): Boolean;
external 'RunTask@{app}\ISTask.dll stdcall uninstallonly';

PS: В директории Inno Setup\Examples есть пример CodeDll.iss, посмотри его.

Пишет дублирование функций. Я смотрел пример в CodeDll.iss. Я не могу придумать как сделать чтоб работало для удаления и перед установкой.

Source: ISTask.dll; DestDir: "{app}"
 
function KillTask(ExeFileName: string): Integer;
external 'KillTask@ISTask.dll stdcall setuponly';

Код не работает

Source: ISTask.dll; DestDir: "{app}"
 
function KillTask(ExeFileName: string): Integer;
external 'KillTask@{app}\ISTask.dll stdcall setuponly';

Тоже не работает. Почему то только работает первый вариант.

Source: ISTask.dll; DestDir: "{app}"
 
function KillTask(ExeFileName: string): Integer;
external 'KillTask@files:ISTask.dll stdcall delayload';

Может будут какие то идеи по этому поводу.

Цитата Craft @ 14.02.11, 15:36

Я смотрел пример в CodeDll.iss

...и не заметил, что там показано как раз то, что тебе и нужно.

[Files]
Source: ISTask.dll; DestDir: "{app}"
 
[Code]
function KillTask(ExeFileName: string): Integer;
external 'KillTask@files:ISTask.dll stdcall setuponly';
      
function RunTask(FileName: string; bFullpath: Boolean): Boolean;
external 'RunTask@files:ISTask.dll stdcall setuponly';
      
      
function KillTaskU(ExeFileName: string): Integer;
external 'KillTask@{app}\ISTask.dll stdcall uninstallonly';
      
function RunTaskU(FileName: string; bFullpath: Boolean): Boolean;
external 'RunTask@{app}\ISTask.dll stdcall uninstallonly';

Так дублирования не будет т.к. ф-ции для деинсталляции импортируются в скрипт под другим названием (с суффиксом U например).

Цитата mitrich @ 15.02.11, 10:44

Цитата Craft @ 14.02.11, 15:36

Я смотрел пример в CodeDll.iss

...и не заметил, что там показано как раз то, что тебе и нужно.

[Files]
Source: ISTask.dll; DestDir: "{app}"
 
[Code]
function KillTask(ExeFileName: string): Integer;
external 'KillTask@files:ISTask.dll stdcall setuponly';
      
function RunTask(FileName: string; bFullpath: Boolean): Boolean;
external 'RunTask@files:ISTask.dll stdcall setuponly';
      
      
function KillTaskU(ExeFileName: string): Integer;
external 'KillTask@{app}\ISTask.dll stdcall uninstallonly';
      
function RunTaskU(FileName: string; bFullpath: Boolean): Boolean;
external 'RunTask@{app}\ISTask.dll stdcall uninstallonly';

Так дублирования не будет т.к. ф-ции для деинсталляции импортируются в скрипт под другим названием (с суффиксом U например).

Кстати так вчера и сделал .

Блин, я тоже просмотрел

Подскажите где взять istask.dll? в папке innosetup его нет.

Уже и не помню, откуда я его скачал...
Прикреплённый файлISTask.zip (36,3 Кбайт, скачиваний: 375)