Редактор свойств для выбора файла

[TechnoMag]

Вместо диалогового окна открытия файлов создаваемое в процедуре Edit, появляется диалоговое окно открытия файлов с параметрами по умолчанию. Т.е. даже фильтр *.* Похоже, что процедура не срабатывет.
Как решить проблему?

unit desMBList;
 
interface
uses
SysUtils, DesignIDE, DesignEditors, DesignIntf, TypInfo, Dialogs, MBList1;
 
type
 
TFileNameProperty = class(TPropertyEditor) // редактор свойств для выбора файла XML
  public
    function GetAttributes: TPropertyAttributes; override;
    procedure Edit; override;
  end;
 
  procedure Register;
 
implementation
 
procedure Register;
begin
  RegisterPropertyEditor(TypeInfo(TFileName), TMBList, 'XMLDocumentPath', TFileNameProperty);
end;
 
function TFileNameProperty.GetAttributes: TPropertyAttributes;
  begin
    Result := [paDialog];
  end;
 
procedure TFileNameProperty.Edit;
var
  OpenDialog: TOpenDialog;
begin
  OpenDialog:=TOpenDialog.Create(nil);
  try
    OpenDialog.Title := 'Выберите xml файл.';
    OpenDialog.FileName := '';
    OpenDialog.Filter := 'XML Files (*.xml)|*.xml';
    OpenDialog.HelpContext := 0;
    OpenDialog.Options := OpenDialog.Options + [ofPathMustExist, ofFileMustExist, ofForceShowHidden];
    if OpenDialog.Execute then
      //SetValue(OpenDialog.Filename);
  finally
    OpenDialog.Free;
  end;
end;
 
end.

Я реорганизовал проект, как было расписано в Где искать DsgnIntf.dcu, DesignIDE.dcu и Proxies.pas?. Но, похоже, что вышеуказанный (Design-time) код не присоединяется к коду компонента (Run-time).

Сообщение отредактировано: TechnoMag - 06.12.10, 23:52

[DimaBr]

1. Добавьте desMBList в инсталиционный пакет
2. Добавьте в пакет DesignIde.dcp (DelphiX\Lib)
3. Instal

[TechnoMag]

Цитата DimaBr @ 07.12.10, 06:33

1. Добавьте desMBList в инсталиционный пакет

Если вы о uses, то выдается ошибка Circular unit references, т.к. по инструкции (ссылку я указал выше) в desMBList в uses я указал MBList (главный пакет).
Если о desMBList.dcp то не работает. Вроде даже не привязывается этот файл.

[DimaBr]

У вас есть пакет, которым вы инсталлируете свой компонент в палитру. Вот туда и нужно добавить файл регистрации редактора свойства, а в Requires - DesignIde. Делается это кнопочкой Add.

[TechnoMag]

Пробовал. Может у Вас получится. Вполне вероятно, что я не правильно реорганизовал прект. Delphi 7.

MsBList.7zMBList.7z (16,01 Кбайт, скачиваний: 178)

[DimaBr]

1. Уберите в desMBList "uses DesignIDE"
2. Уберите из первого пакета DesignIDE
3. Добавьте во второй пакет DesignIDE

[TechnoMag]

Цитата DimaBr @ 07.12.10, 12:41

1. Уберите в desMBList "uses DesignIDE"
2. Уберите из первого пакета DesignIDE
3. Добавьте во второй пакет DesignIDE

Что считать первым пакетом, что вторым?

[DimaBr]

В приложенном примере два пакета (dpk) (Хотя это можно объеденить и в один).
Первый пакет Package1.dpk инсталирует компонент в палитру компонентов. (если в опциях поставить RunTime Only), то будет возможность подгружать ваш компонент в приложение в виде библиотеки (bpl), но об этом пока рано.
Второй пакет desPackage1.dpk инсталирует редактор свойства. На нём стоит галочка DedignTime Only и это правильно !

Если вы не собираетесь использовать компонент в библиотеках, динамически подгружать (LoadLibrary), и динамически создавать, то можно объединить RunTime и DesignTime в один пакет, поставить соответствующую галочку добавить оба ваших файла (с компонентом и редактором), добавить пакет дизайнера - DesignIde.

[TechnoMag]

При попытке инсталляции объединенного компонента (с файлами MBList.pas и desMBList.pas в одном пакете .bpl) IDE намертво виснет. Такое же было когда весь код был в одном файле.

[DimaBr]

Повторяю ещё раз, выполните пункт № 1. Уберите DesignIDE в секции USES файла desMBList.pas

[TechnoMag]

Ура получилось установить компонент!
Но в редакторе свойств после выбора файла пишет [Unknown]

unit desMBList;
 
interface
uses
Forms, Classes, SysUtils, DesignEditors, DesignIntf, TypInfo, Dialogs, MBList1;
 
type
 
TFileNameProperty = class(TPropertyEditor) // редактор свойств для выбора файла XML
  public
 
    function GetAttributes: TPropertyAttributes; override;
    procedure Edit; override;
  end;
 
  procedure Register;
 
implementation
 
procedure Register;
begin
  RegisterPropertyEditor(TypeInfo(TFileName), TMBList, 'XMLDocumentPath', TFileNameProperty);
end;
 
function TFileNameProperty.GetAttributes: TPropertyAttributes;
  begin
    Result := [paDialog];
  end;
 
procedure TFileNameProperty.Edit;
begin
  with TOpenDialog.Create(Application) do
  try
    Filter := 'XML Files (*.xml)|*.xml';
    Title := 'Выберите файл со списком параметров';
    HelpContext := 0;
    FileName := GetStrValue;
    Options := Options + [ofPathMustExist, ofFileMustExist, ofForceShowHidden];
    if Execute then
      SetStrValue(FileName);
  finally
    Free;
  end;
end;
 
end.

Сообщение отредактировано: TechnoMag - 09.12.10, 23:57

[DimaBr]

TFileNameProperty = class(TStringProperty)

[TechnoMag]

Спасибо! Бальшущий вопрос решен.