Как вызвать событие? , Есть поток из него надо вызвать событие

[v1m]

Цитата arj99 @ 02.07.10, 08:53

Handle должен передать сам компонент при запуске потока, удобнее всего параметром конструктора.

то есть
я должен при создании компонента должен передать ему Handle окна?

[leo]

Можно создать свое невидимое окно, как это делается в TTimer. См. AllocateHwnd, DeallocateHwnd

Что касается RecThread, то по моему это должен быть чисто вспомогательный зависимый класс, который можно полностью упрятать в implementation, а в компоненте ссылку на него объявить просто как TThread

[v1m]

Цитата leo @ 01.01.70, 00:00

Что касается RecThread, то по моему это должен быть чисто вспомогательный зависимый класс, который можно полностью упрятать в implementation, а в компоненте ссылку на него объявить просто как TThread

То есть? напиши по подробней

Сообщение отредактировано: v1m - 02.07.10, 16:45

[leo]

Как-то так:

type
  TReadEvent = procedure(Data:pAnsiChar;Size:integer) of object;
  vmUDPSocket = class(TComponent)
  private
    ...
    FWnd:cardinal;       //окно
    FRecvThr:TThread;    //поток
    FOnRead:TReadEvent;  //внешний обработчик события
    procedure WndMethod(var Message: TMessage); //процедура окна
    procedure StartThread;
  protected
    ...
  public
    ...
    property OnRead:TReadEvent read FOnRead write FOnRead;
  end;
 
implementation
var
  WM_MyRecvData:cardinal;
 
type
  TRecvThread = class(TThread)
    Owner:vmUDPSocket; //владелец
    constructor Create(AOwner:vmUDPSocket);
    procedure Execute; override;
  end;
constructor TRecvThread.Create(AOwner:vmUDPSocket);
begin
  inherited Create(false);
  Owner:=AOwner;
  FreeOnTerminate:=true; //???
end;
procedure TRecvThread.Execute;
var
  buf:array[0..???] of AnsiChar;
  data:pAnsiChar;
  len:integer;
begin
  while not Terminated do
  begin
    len:=recv(Owner.Socket,buf,sizeof(buf),0);
    if len > 0 then
    begin
      GetMem(data,len);
      Move(buf,data^,len);
      SendMessage(Owner.FWnd,WM_MyRecvData,Integer(data),len);  
    end
    else
      ...
  end;
end;
 
//-------------------
 
procedure vmUDPSocket.WndMethod(var Message: TMessage);
begin
  with Message do
    if Msg = WM_MyRecvData then
    begin
      if Assigned(FOnReadData) then
        FOnReadData(pointer(wParam),lParam);
      FreeMem(pointer(wParam));
      Result:=0;
    end
    else
      Result:=DefWindowProc(FWnd,Msg,wParam,lParam);
end;
 
procedure vmUDPSocket.StartThread;
begin
  WM_MyRecvData:=RegisterWindowMessage('WM_MyRecvData');
  if FWnd = 0 then
    FWnd:=AllocateHwnd(WndMethod);
  FRecvThr:=TRecvThread.Create(Self);
end;

Сообщение отредактировано: leo - 02.07.10, 17:50

[v1m]

спс сейчас код просмотрел попробую реализовать...

[leo]

Кстати, если передавать данные синхронно через SendMessage, то и динамическую память под данные не обязательно выделять\освобождать - можно прямо передавать указатель на локальный буфер buf

[v1m]

вот так?
SendMessage(Owner.FWnd,WM_MyRecvData,Integer(buf),len);

[leo]

Integer(@buf)

[v1m]

спс!!!!!!!
все работает!!
arj99 и leo отдельное СПС!
и еще вопрос как добавить несколько параметров в сообщении?
на пример мне надо еще добавить от кого пришло сообщение..

Сообщение отредактировано: v1m - 03.07.10, 10:20

[leo]

Цитата v1m @ 03.07.10, 10:16

все работает!!

Только не забудь довести все это "сырье" до ума, в частности добавить DeallocateHwnd в деструктор

Цитата v1m @ 03.07.10, 10:16

как добавить несколько параметров в сообщении?

Еще проще\нагляднее чем с разрощненной парой - просто cложить все необходимые данные в record и передавать указатель на нее, например:

type
  pRecvData = ^TRecvData;
  TRecvData = record
    Data:pChar;
    DataSize:integer;
    From:pChar;
    Reserved:integer;
  end;
  TReadEvent = procedure(const Data:TRecvData) of object;
 
  //посылка сообщения
  with Data do
  begin
    Data:=buf;
    DataSize:=len;
    From:=...;
  end;
  SendMessage(Owner.FWnd,WM_MyRecvData,integer(@Data),0);
 
  //прием сообщения
  if (wParam <> 0) and Assigned(FOnReadData) then
    FOnReadData(pRecvData(wParam)^);

Сообщение отредактировано: leo - 03.07.10, 11:24

[Демо]

v1m

Я бы рекомендовал разобраться как реализован TThread.
В этом случае 99% вопросов просто отпадёт за ненадобностью.

[v1m]

Цитата leo @ 03.07.10, 11:13

Только не забудь довести все это "сырье" до ума, в частности добавить DeallocateHwnd в деструктор

добавил уже))

Цитата Демо @ 03.07.10, 13:18

Я бы рекомендовал разобраться как реализован TThread.

я читал по TThread но видимо не то читал)

[Демо]

Цитата v1m @ 04.07.10, 05:42

я читал по TThread но видимо не то читал)

Я говорил не про статьи и справку, а про исходники TThread.

[v1m]

ааа