Прогулка по окнам Windows
, Обобщающие сведения
![]() |
Наши проекты:
Журнал · Discuz!ML · Wiki · DRKB · Помощь проекту |
|
| ПРАВИЛА | FAQ | Помощь | Поиск | Участники | Календарь | Избранное | RSS |
| [216.73.216.88] |
|
|
Прогулка по окнам Windows
, Обобщающие сведения
|
Сообщ.
#1
,
|
|||||
|
|
Прогулка по окнам Windows.
Иерархия окон в системе представлена таким образом:
Перейдём к иструментарию Windows API, позволяющему реализовать сказаное выше.
О Z-упорядочивании: самое <верхнее> окно на экране имеет нулевую позицию, следующее, перекрываемое им окно - первую позицию, и так далее до самого <нижней> части экрана. Таким образом реализуется понятие трёхмерности, хотя в одной умной книжке я читал, что многооконная среда условно имеет 2.5-мерность (2.5D). С помощью этой функции мы можем получить список всех окон системы несложной рекурсивной прогулкой по дереву (задача 1-го курса ВУЗа <Обход дерева>).Нам понадобятся ещё несколько функций WinAPI: function GetWindowText(hWnd: HWND; lpString: PChar; nMaxCount: Integer): Integer; Функция получает текст окна по его идентификатору и возвращает считанную длину строки текста окна.
Функция возвращает идентификатор меню по переданному идентификатору окна. Перейдём к непосредственному построению программы.
Добавим в форму fmMain процедуру заполнения дерева FillTree следующего содержания:
// процедура заполнения дерева
procedure TfmMain.FillTree;
var
h,h1:THandle;
Buffer:PChar;
// рекурсивная процедура заполнения дерева
procedure RegisterWindow(hWnd:THandle;ParentTreeItem:TTreeNode);
var
Node:PNode; // данные окна
TreeNode:TTreeNode; // узел дерева
h:THandle; // хэндл окна, промежуточная переменная
begin
// получение и сохранение информации об окне
// создание переменной информации обокне
New(Node);
// присвоение дескриптора
Node^.Handle:=hWnd;
// получение текста окна
GetWindowText(hWnd,Buffer,256);
Node^.Text:=Trim(StrPas(Buffer));
// получение класса окна
GetClassName(hWnd,Buffer,255);
Node^.CName:=Trim(StrPas(Buffer));
// получение дескриптора меню окна
Node^.Menu:=GetMenu(hWnd);
// размещение в дереве
TreeNode:=Tree.Items.AddChild(ParentTreeItem,'');
// присвоение отображаемого текстового значения
if Node^.Text<>'' then TreeNode.Text:=Node^.Text
else if Node^.CName<>'' then TreeNode.Text:=Node^.CName
else TreeNode.Text:=IntToStr(Node^.Handle);
// сохранение ссылки на информацию об окне в соответствующем узле дерева
TreeNode.Data:=Node;
// Рекурсивные вызовы
// получение поддчинённых элементов
h:=GetWindow(hWnd,gw_Child);
if h<>0 then
RegisterWindow(h,TreeNode);
// получение элеметов того же уровня
h:=GetWindow(hWnd,gw_hWndNext);
if h<>0 then
RegisterWindow(h,ParentTreeItem);
end;
begin
// сообщение в строке статуса
Status.SimpleText:='Обновление информации об окнах ...';
Application.ProcessMessages;
// выключение отображения изменений дерева
Tree.Items.BeginUpdate;
// очистка дерева
Tree.Items.Clear;
// создание буфера для работы с PChar
Buffer:=StrAlloc(256);
// Получаем хэндл текущего окна
h1:=Handle;
repeat
// получаем хэндл окна-владельца
h:=GetWindow(h1,GW_OWNER);
// если не окно верхнего уровня, то ищем дальше
if h<>0 then begin
h1:=h;
end;
until h=0;
// находим первое верхнее окно
h:=GetWindow(h1,GW_HWNDFIRST);
// запуск рекурсии
RegisterWindow(h,nil);
// задание выделенного элемента дерева
Tree.Selected:=Tree.Items[0];
// включение отображения изменений дерева
Tree.Items.EndUpdate;
// удаление буфера для работы с PChar
StrDispose(Buffer);
// сообщение в строке статуса
Status.SimpleText:='Готово.';
end;
Теперь попробуем в ней разобраться (смотри по тексту процедуры). Status - класс TStatus Bar. Сообщим в строке статуса, что мы обновляем информацию. Выключим отображение обновления дерева для того, чтобы ничего в процессе обновления у нас на экране не дёргалось. Очистим дерево и создадим переменную Buffer, в которую будем записывать строковые результаты выполнения функций WinAPI.
Следующий этап - добраться до самого верхнего и самого первого окна системы. Мы вызываем функцию GetWindow с параметром GW_OWNER - получение окна-владельца, начиная с главного окна программы. Получив окно, не имеющее владельца, находим для этого окна окно с нулевым Z-порядком, вызвав функцию GetWindow с параметром GW_HWNDFIRST - получение первого окна в данном уровне вложенности. Теперь мы можем начать обход дерева окон, начиная с самого первого по порядку возрастания вложенности и Z-порядка, вызвав рекурсивную процедуру RegisterWindow.
Как известно, у класса TTreeNode - узла дерева - есть поле Data:Pointer. В это поле можно записывать любые ссылки на данные, которые требуется ассоциировать с узлом дерева. Создадим структуру данных для хранения информации об окне.
// тип для хранения информации об окне TNode=record Handle:THandle; // хэндл окна Text:string[255]; // текст окна CName:string[255]; // имя класса Menu:HMenu; // хендл меню end; PNode=^TNode; // указатель на структуруПри нахождении очередного окна будем создавать динамическую переменную типа PNode и её значение записывать в поле TTreeNode.Data. Итак, мы знаем <первое верхнее> окно. Передадим его в процедуру RegisterWindow. Также в эту процедуру передаётся ссылка на узел дерева, к которому добавляются узлы подчинёных окон. В первом случае вызова рекурсии, эта ссылка равна nil. Следующие действия просты до безобразия (процедура RegisterWindow):
// действие "обновить" procedure TfmMain.acRefreshExecute(Sender: TObject); begin // заполнение дерева FillTree; end;Теперь мы можем принудительно обновлять список. Перейдём к отображению всей собранной информации об окне в компоненте List:TListView. Обработаем событие TTreeView.OnChange так: // событие изменения выделенного элемента дерева
procedure TfmMain.TreeChange(Sender: TObject; Node: TTreeNode);
// добавление в List строки
procedure AddItem(Name,Value:String);
var
Item:TListItem;
begin
Item:=List.Items.Add();
Item.Caption:=Name;
Item.SubItems.Add(Value);
end;
begin
// выключение обновления
List.Items.BeginUpdate;
// очистка
List.Items.Clear;
// добавление элементов
if (Node<>nil) and (Node.Data<>nil) then begin
AddItem('Текст',TNode(Node.Data^).Text);
AddItem('Класс',TNode(Node.Data^).CName);
AddItem('Дескриптор окна',IntToStr(TNode(Node.Data^).Handle));
AddItem('Дескриптор меню',IntToStr(TNode(Node.Data^).Menu));
end;
// включение обновления
List.Items.EndUpdate;
end;
На выделение соответсвующего элемента дерева (Node:TTreeNode), добавляем в компонент List:TListView строки со значениями всех полей записи PNode^.
Всё!
Cкачать проект:
Максим Мазитов |
|
Сообщ.
#2
,
|
|
|
|
Оригинал статьи расположен по адресу http://www.delphikingdom.com/helloworld/windows.htm
|