Как перебрать все CheckBox'ы на листе?? , ???

Суть проблемы такова:

На листе имеется порядка 70 записей, напротив каждой стоит CheckBox1, CheckBox2,.... и т.д.

Требуется создать Кнопку "Отметить все" то есть Все CheckBox.Value = True

CheckBox1.Value = True
CheckBox2.Value = True
.....
CheckBox69.Value = True
CheckBox70.Value = True

Так все дело работает.

А можно ли сделать это грубо говоря так ???

for i=1 to 70
CheckBox(i).Value = true
Next

for i=1 to 70
  Controls("CheckBox" & CStr(i)).Value = true
Next

Цитата Akina @ 27.01.10, 05:52

for i=1 to 70
  Controls("CheckBox" & CStr(i)).Value = true
Next

ругается на Controls "Sub or Function not defined"
Может объявить что то надо???

Ну напиши Me.Controls

Цитата Akina @ 27.01.10, 06:06

Ну напиши Me.Controls

Все равно ругается "Method or data member not found"

Зазипуй файл и приложи к сообщению

Цитата Akina @ 27.01.10, 06:47

Зазипуй файл и приложи к сообщению

Вот!
Прикреплённый файлОбщая.zip (82.97 Кбайт, скачиваний: 315)

Dim CheckBoxName As String
Dim CheckBoxObject As Variant
 
For i = 1 To 70
    CheckBoxName = "CheckBox" & CStr(i)
    Set CheckBoxObject = Me.Evaluate(CheckBoxName)
    CheckBoxObject.Object.Value = True
Next

Респект и уважуха ))))
Я два дня голову ломаю
Синтаксис ё-маё


Все получилось ))

Сообщение отредактировано: calam4uk - 27.01.10, 07:44

Цитата calam4uk @ 27.01.10, 07:44

Синтаксис ё-маё

Я расписАл в три строки, чтобы было понятно, как всё происходит. Но можно собрать всё это в одну строку и не использовать промежуточных переменных.

Цитата Akina @ 27.01.10, 08:00

Цитата calam4uk @ 27.01.10, 07:44

Синтаксис ё-маё

Я расписАл в три строки, чтобы было понятно, как всё происходит. Но можно собрать всё это в одну строку и не использовать промежуточных переменных.

Да это я понял!!!
Спасибо)))

calam4uk, вот Вам ещё один вариант:

Option Compare Text
...
Dim objControl As Control
For Each objControl In Me.Controls
    If TypeName(objControl) = "CheckBox" Then
        objControl.Value = False
    End If
Next

Кстати, учтите, что при установке значения "коробочки" произойдёт вызов соответствующего обработчика события Click.

Сообщение отредактировано: Dmitrii - 28.01.10, 07:17

Dmitrii, посмотри его файл. Контролы - не на форме, так что не сработает.

Цитата Akina @ 28.01.10, 07:38

Контролы - не на форме...

Тогда так:

Option Compare Text
...
Dim objControl As OLEObject
For Each objControl In Me.OLEObjects
    If Left(objControl.Name, 8) = "CheckBox" Then
        Me.Shapes(objControl.Name).OLEFormat.Object.Object.Value = False
    End If
Next

Код надо разместить в модуле листа, "контролы" которого обрабатываются.


calam4uk, если вдруг захотите использовать "коробочки" из панели "Формы", а не из панели "Элементы управления", то обращение к ним можно организовать так:

Sub Example()
For i = 1 To ActiveSheet.CheckBoxes.Count
    ActiveSheet.CheckBoxes(i).Value = False
Next
End Sub

Сообщение отредактировано: Dmitrii - 28.01.10, 13:17