Помогите с винграфом , Free Pascal WinGraph

[geshtat]

Здравствуйте,уважаемые форумчане,как исправить это код для Free pascal WinGraph?

uses crt,graph;
const n=3000;
var x,y:array[1..n] of integer;
    k,i,xc,yc:integer;
BEGIN
        cleardevice;
        randomize;
        xc:=0;
        initgraph(xc,yc,'');
        xc:=getmaxX;
        yc:=getmaxY;
        for k:= 1 to N do
         begin
                X[k]:=random(xc);
                Y[k]:=random(yc)
         end;
         Repeat
          for k:= 1 to N do
           begin
                 i:= random(16);
                 PutPixel(X[k], Y[k], i);
              if i= 0 then
               begin
                 X[k]:= random(xc);
                 Y[k]:= random(yc)
               end
           end;
                    delay(160);
         Until KeyPressed;
END.

[volvo877]

Например, вот так:

uses
   crt, wingraph; // graph;
 
const
   n = 3000;
 
var
   x, y : array [1..n] of integer;
   k, i, xc, yc : integer;
   gd, gm : integer;
 
const
   clrs : array[0 .. 15] of ^longword =
   (
      @Black, @Blue, @Brown, @Cyan, @DarkGray, @Green, @LightBlue,
      @LightCyan, @LightGray, @LightGreen, @LightMagenta, @LightRed,
      @Magenta, @Red, @White, @Yellow
   );
 
BEGIN
   randomize;
   gd := d4bit;
   gm := m640x480;
   InitGraph(gd, gm, 'WinGraph');
 
   cleardevice;
   xc:=getmaxX;
   yc:=getmaxY;
   for k:= 1 to N do
   begin
      X[k]:=random(xc);
      Y[k]:=random(yc)
   end;
 
   repeat
      for k:= 1 to N do
      begin
         i:= random(16);
         PutPixel(X[k], Y[k], clrs[i]^);
         if i= 0 then
         begin
            X[k]:= random(xc);
            Y[k]:= random(yc)
         end
      end;
      delay(160);
   until KeyPressed;
   CloseGraph;
 
END.

P.S. Переношу в 32-битные...

[geshtat]

Спасибо большое, а я-то, идиот, забыл что он цвет словами только понимает...