НЕ Резидентный драйвер клавиатуры -> Форум на Исходниках.RU [Powered by Invision Power Board]

<{CODE_COLLAPSE_OFF}><{CODE_WRAP_OFF}>

; файл kbddrv.asm

; tasm /m3 kbddrv

; tlink kbddrv

; exetobin kbddrv

ideal

model tiny

codeseg

org 0

EntryPoint: ; тасм не может без этого

KEYBUF_SIZE equ 20h

; заголовок драйвера

dd -1 ; поле связи со следующим драйвером

dw 1000100000000010b ; атpибуты дpайвеpа

dw Func_Strat ; подпрограмма стратегии

dw Func_Intr ; подпрограмма прерывания

db 'KBDDRV ' ; имя драйвера

functab:

dw Init ; функция 0: инициализация

dw Dummy ; функция 1: пpовеpка носителя

dw Dummy ; функция 2: создать BPB

dw NotSupport ; функция 3: чтение с контpолем в/в

dw Read ; функция 4: чтение

dw Get ; функция 5: ненаpушающее чтение

dw Dummy ; функция 6: состояние ввода

dw Clear ; функция 7: очистить буфеp ввода

dw NotSupport ; функция 8: запись

dw NotSupport ; функция 9: запись с веpификацией

dw NotSupport ; функция 10: состояние вывода

dw NotSupport ; функция 11: очистить буфеp вывода

dw NotSupport ; функция 12: запись с контpолем в/в

dw Dummy ; функция 13: откpыть (dos 3.0 и выше)

dw Dummy ; функция 14: закpыть

dw Dummy ; функция 15: сменяемый носитель

dw NotSupport ; функция 16: выводить, пока не будет занято

BlockPtr dd ? ; адрес переданного блока данных

Head dw 0

Tail dw 0

KeyBuf db KEYBUF_SIZE dup(?) ; внутренний буфер для приема символов

; подпрограмма стратегии

proc Func_Strat far

; просто сохраняем адрес блока данных

mov [word cs:BlockPtr+2], es

mov [word cs:BlockPtr], bx

ret

endp

; подпрограмма прерывания

proc Func_Intr far

pushf

push ax bx cx dx si di bp ds es

; настраиваем сегментный регистр данных

push cs

pop ds

; получаем адрес блока данных

les di, [BlockPtr]

; переходим на требуюмую функцию

xor bh, bh

mov bl, [es: di+2] ; bx - номер функции

cmp bl, 16 ; 16 - макс. номер функции

jbe @@jmptofunc ; <- все ОК

mov ax, 8003h ; код - ошибка: неправильная команда

jmp @@quit

@@jmptofunc:

shl bx, 1

call [word functab+bx] ; вызываем функцию

les di, [BlockPtr]

@@quit:

or ax, 100h ; устанавливаем бит окончания операции

mov [es: di+3], ax ; сохраняем статус

pop es ds bp di si dx cx bx ax

popf

ret

endp

; пустышка

proc Dummy near

xor ax, ax ; очищаем бит занятости

ret

endp

; извещает о неподдерживаемых функциях

proc NotSupport near

mov ax, 8003h ; код - ошибка: неправильная команда

ret

endp

; сохраняет символ во внутренний буфер

proc storechar near

mov [KeyBuf+bx], al

inc bx

cmp bx, KEYBUF_SIZE

jne @@end

xor bx, bx

@@end:

ret

endp

; читает символ с внутреннего буфера

proc loadchar near

mov al, [KeyBuf+si]

inc si

cmp si, KEYBUF_SIZE

jne @@end

xor si, si

@@end:

ret

endp

; функция 4: чтение заданного количества символов

proc Read near

push es di

mov cx, [es: di+18] ; cx - количество символов

jcxz @@end ; если 0 то выходим

les di, [es: di+14] ; es:di - адрес символьного буфера

mov bx, [Head] ; si,bx - состояние внутреннего буфера

mov si, [Tail]

cld ; будем использовать STOSB

@@read:

cmp si, bx ; буфер пуст?

jne @@inbuff ; <- нет, читаем из него

@@getkey:

xor ah, ah ; считываем символ с буфера клавиатуры

int 16h

call storechar ; сохраняем во внутренний буфер

or al, al ; не расширенный ли код пришел?

jnz @@inbuff ; <- нет

mov al, ah ; сохраняем расширенный код

call storechar

@@inbuff:

call loadchar

stosb ; отправляем символ в буфер

loop @@read ; повторяем, пока не считаем все требуемые символы

mov [Head], bx ; сохраняем значения внутреннего буфера

mov [Tail], si

@@end:

pop di es

xor ax, ax

ret

endp

; функция 5: ненаpушающее чтение

proc Get near

; проверяем внутренний буфер на наличие не считанных символов

mov si, [Tail]

mov al, [KeyBuf+si]

cmp si, [Head]

jne @@store

; внутренний буфер пуст, читаем с буфера клавиатуры

@@getkey:

mov ah, 1 ; проверяем буфер клавиатуры на наличие

int 16h ; несчитанных символов

jz @@error

@@store:

mov [es: di+13], al ; сохраняем символ в блоке данных

xor ax, ax ; все OK

ret

@@error:

mov ax, 100h ; устанавливаем признак занятости (нет символа)

ret

endp

; функция 7: очистить буфеp ввода

proc Clear near

; очищаем буфер клавиатуры

mov ah, 1 ; проверяем буфер клавиатуры на наличие

int 16h ; несчитанных символов

jz @@end

xor ah, ah ; считываем

int 16h

jmp Clear ; повторяем, пока не считаем все символы

@@end:

xor ax, ax ; все OK

; очищаем и внутренний буфер

mov [Tail], ax

mov [Head], ax

ret

endp

; инициализация драйвера

proc Init near

; устанавливаем конечный адрес драйвера

; поскольку инициализация больше не потребуется, отбрасываем и эту подпрограмму

lea ax, [Init]

mov [es: di+14], ax

mov [es: di+16], cs

xor ax, ax ; все ОК

ret

endp

end EntryPoint