Редакторы свойств для выбора директории и показа диалога about. , Редакторы свойств для выбора директории и показа диалога about.

[SkAndriy]

Доброе утро!

Два вопроса по редакторам свойств.

Первый редактор должен показать в свойстве Directory или Folder папку, которую я выбираю в диалоге OpenDialog:

unit FileName;
 
interface
uses
  Windows, Messages, SysUtils, Variants, Dialogs, DesignIntf, Classes, Forms,
  DesignEditors, TypInfo;
 
type
  TFileNameProperty = class(TPropertyEditor)
  public
    function GetAttributes: TPropertyAttributes; override;
    procedure Edit; override;
  end;
 
  procedure Register;
 
implementation
 
function TFileNameProperty.GetAttributes: TPropertyAttributes;
begin
  Result := [paDialog]
end;
 
procedure TFileNameProperty.Edit;
begin
  with TOpenDialog.Create(Application) do
  try
      Title := GetName; { name of property as OpenDialog caption }
      Filename := GetValue;
      Filter := 'All Files (*.*)|*.*';
      HelpContext := 0;
      Options := Options + [ofShowHelp, ofPathMustExist, ofFileMustExist];
      if Execute then
        SetValue(Filename);
  finally
      Free
  end
end;
 
procedure Register;
begin
  RegisterPropertyEditor(TypeInfo(TFileName), nil, '', TFileNameProperty)
end;

Но, я получаю весь путь с файлом. Как правильно изменить код, чтобы получать только нужную директорию?

Второй редактор должен в свойстве About просто показать форму. Примерный код ниже:

unit AboutDlg;
 
interface
 
uses Windows, Messages, SysUtils, Variants, DesignIntf, Classes, Forms,
     DesignEditors, TypInfo, AboutDlgForm, Controls, MyComponent3;
 
type
  TAboutDlgProperty = class(TStringProperty)
  public
    function GetAttributes: TPropertyAttributes; override;
    procedure Edit; override;
    function MyComponent: TMyComponent;
  end;
 
implementation
 
function TAboutDlgProperty.GetAttributes: TPropertyAttributes;
begin
  Result := [paDialog]
end;
 
procedure TAboutDlgProperty.Edit;
begin
  AboutForm := TAboutForm.Create(nil);
  try
    // show the dialog box
    if AboutForm.ShowModal = mrOK then
      Set?????Value(??????????);
  finally
    AboutForm.Free;
  end;
end;
 
function TAboutDlgProperty.MyComponent : TMyComponent;
begin
  Result := GetComponent(0) as TMyComponent;
end;
 
procedure Register;
begin
  RegisterPropertyEditor(TypeInfo(Integer), TMyComponent, 'About', TAboutDlgProperty)
end;
 
end.

Что неверно прописано в коде, чтобы открывать форму диалога About?
Как нужно в данном случае прописывать процедуру Edit?

Спасибо.

Сообщение отредактировано: SkAndriy - 02.09.10, 08:26

[DimaBr]

1. ExtractFilePath
2. Свойство About обычно не устанавливают, следовательно Set?????Value - не нужно

[Light13]

касательно первого,
ExtractFileDir
либо
SelectDirectory из QDialogs

второй вопрос не совсем понял

[SkAndriy]

Да, если я использую конструкцию:

procedure TFileNameProperty.Edit;
begin
  with TOpenDialog.Create(nil) do
  try
      Title := GetName; { name of property as OpenDialog caption }
      FileName := GetValue;
      Filter := 'All Files (*.*)|*.*';
      HelpContext := 0;
      Options := Options + [ofShowHelp, ofPathMustExist, ofFileMustExist];
      if Execute then
        SetValue(ExtractFileDir(FileName));
  finally
      Free
  end
end;

То в свойство компонента прописывается путь к директории, где он лежит.
Но, мне нужно просто выделит директорию и все.
Мне не нужно искать и выделять файл. Как в этом случае поступить.

По второму вопросу:

Я хочу просто показать диалог (свою форму) с информацией о компонента.
Как изменить выше приведенный код в этом случае?
Если Set?????Value не нужно, то что нужно указать?

Спасибо.

[SkAndriy]

Первый вопрос решил заменив ЕOpenDialog на TFolderDialog.

а вот воторой вопрос не получается решить.
Нужно просто показать форму-диалог "О компоненте".
Как это сделать корректно?
Спасибо

Сообщение отредактировано: SkAndriy - 02.09.10, 09:52

[DimaBr]

1. С помощью OpenDialod нельзя выбрать папку, используйте SelectDirectory или SHBrowseForFolder.
2. Ничего не нужно указывать, вы же ничего не присваиваете свойству.

procedure TAboutDlgProperty.Edit;
begin
  with TAboutForm.Create(nil) do
    try
      ShowModal
    finally
      Free;
    end;
end;

[SkAndriy]

Не получается вызвать форму-диалог About.
Нет в свойстве кнопки с тремя точками.

Привожу код вцелом:

unit AboutDlg;
 
interface
 
uses Windows, Messages, SysUtils, Variants, DesignIntf, Classes, Forms,
     DesignEditors, TypInfo, AboutDlgForm;
 
type
  TAboutDlgProperty = class(TStringProperty)
  public
    function GetAttributes: TPropertyAttributes; override;
    procedure Edit; override;
  end;
 
implementation
 
function TAboutDlgProperty.GetAttributes: TPropertyAttributes;
begin
  Result := [paDialog]
end;
 
procedure TAboutDlgProperty.Edit;
begin
  with TAboutForm.Create(nil) do
  try
      ShowModal
  finally
      Free;
  end;
end;
 
procedure Register;
begin
  RegisterPropertyEditor(TypeInfo(String), TMyComponent, 'About', TAboutDlgProperty)
end;
 
end.

Где ошибка?

Спасибо.

[DimaBr]

А где объявление свойства ?

[SkAndriy]

пробовал и так

property About : Integer read FAbout write FAbout;

в свойстве ноль, кнопка с тремя точками отсутствует

и так

property About : String read FAbout write FAbout;

кнопка есть, но открывается редактор строки? a не моя форма AboutForm.

Может надо как-то иначе?

Спасибо

Сообщение отредактировано: SkAndriy - 02.09.10, 12:19

[DimaBr]

property About: string read fAbout write SetAbout;
 
 
procedure SetAbout;
begin
 // ничего не делаем
end;
 
RegisterPropertyEditor(TypeInfo(string), TMyComponent, 'About', TAboutDlgProperty)

[SkAndriy]

При такой конструкции есть кнопка с тремя точками в свойстве, но после ее нажатия получаем не мое окно About, а окно String-Edit.
Как изменить ситуацию?

Спасибо

Сообщение отредактировано: SkAndriy - 02.09.10, 13:36

[DimaBr]

У редактора String нет дополнительного окна редактирования, что то вы путаете.

TMyComponent = class(TComponent)
  private
    fAbout: string;
    procedure SetAbout(const Value: string);
  published
    property About: string read fAbout write SetAbout;
  end;
 
 TAboutDlgProperty = class(TStringProperty)
  public
    function GetAttributes: TPropertyAttributes; override;
    procedure Edit; override;
  end;
 
 
implementation
 
procedure Register;
begin
  RegisterComponents('Standard', [TMyComponent]);
  RegisterPropertyEditor(TypeInfo(String), TMyComponent, 'About', TAboutDlgProperty)
end;
 
procedure TMyComponent.SetAbout(const Value: string);
begin
end;
 
{ TAboutDlgProperty }
 
function TAboutDlgProperty.GetAttributes: TPropertyAttributes;
begin
  Result := [paDialog];
end;
 
procedure TAboutDlgProperty.Edit;
begin
  with TForm.Create(nil) do
  try
    ShowModal
  finally
    Free;
  end;
end;
 
end.

[SkAndriy]

Доброе утро!

Я так и сделал, точно по Вашему последнему коду, но у меня появляется вот такое диалоговое окно как Вы можете видеть в аттач.
У меня Delphi 2010. Может в этом проблема? Подскажите, Мастера, как все же можно вызвать просто свою собственную форму.

Спасибо.

Прикреплённый файлpropert_editor.jpg (26,96 Кбайт, скачиваний: 540)

[DimaBr]

Не знаю, вот Delphi 2009

Прикреплённый файлMyComponent.JPG (28,55 Кбайт, скачиваний: 561)

[leo]

Думается мне, что процедуру Register нужно либо самому явно вызывать в initialization модуля, либо хотя бы объявить в interface

[DimaBr]

Покажите весь код модуля с формой и регистрацией

[SkAndriy]

с процедурой Register все нормально. вызывается где положено. а выскакивает окно редакторования строки. Почему?
Спасибо

[SkAndriy]

сейчас должен ехать в институт, вечером выложу. спасибо. просто магия какая-то с этим окном.

[SkAndriy]

все получилось, виной модуль стороннего компонента был. спасибо.